3.3.7

libraries/RainMaker/examples/README.md

@@ -0,0 +1,14 @@
+# ESP RainMaker Examples
+
+While building any examples for ESP RainMaker, take care of the following:
+
+1. Change the partition scheme that fits your flash size in Arduino IDE to `RainMaker 4MB`, `RainMaker 4MB no OTA` or `RainMaker 8MB` (Tools -> Partition Scheme -> RainMaker).
+2. Once ESP RainMaker gets started, compulsorily call `WiFi.beginProvision()` which is responsible for user-node mapping.
+3. Use the appropriate provisioning scheme as per the board.
+    - ESP32 Board: BLE Provisioning
+    - ESP32-C3 Board: BLE Provisioning
+    - ESP32-S3 Board: BLE Provisioning
+    - ESP32-S2 Board: SoftAP Provisioning
+    - ESP32-C6 Board: BLE Provisioning
+    - ESP32-H2 Board: BLE Provisioning
+4. Set debug level to Info (Tools -> Core Debug Level -> Info). This is the recommended debug level but not mandatory to run RainMaker.

libraries/RainMaker/examples/RMakerCustom/README.md

@@ -0,0 +1,29 @@
+# ESP RainMaker Custom Device
+
+This example demonstrates how to build a custom device to be used with ESP RainMaker.
+
+## What to expect in this example?
+
+- This example sketch uses the on board Boot button and GPIO16 to demonstrate an ESP RainMaker AC dimmer device.
+- After compiling and flashing the example, add your device using the [ESP RainMaker phone apps](https://rainmaker.espressif.com/docs/quick-links.html#phone-apps) by scanning the QR code.
+- Toggling the state from the phone app will toggle the dimmer state (GPIO16).
+- Pressing the Boot button will toggle the dimmer state (GPIO16) and the same will reflect on the phone app.
+- You can also change the Level from the phone app and see it reflect on the device as a print message.
+
+### Output
+
+```
+[    87][I][RMaker.cpp:13] event_handler(): RainMaker Initialized.
+[    94][I][WiFiProv.cpp:158] beginProvision(): Already Provisioned
+[    95][I][WiFiProv.cpp:162] beginProvision(): Attempting connect to AP: Viking007_2GEXT
+
+Received value = false for Dimmer - Power
+Toggle State to true.
+[ 22532][I][RMakerDevice.cpp:162] updateAndReportParam(): Device : Dimmer, Param Name : Power, Val : true
+
+Received value = 73 for Dimmer - Level
+```
+
+### Resetting the device
+- Press and Hold the Boot button for more than 3 seconds and then release to reset Wi-Fi configuration.
+- Press and Hold the Boot button for more than 10 seconds and then release to reset to factory defaults.

libraries/RainMaker/examples/RMakerCustom/RMakerCustom.ino

@@ -0,0 +1,140 @@
+//This example demonstrates the ESP RainMaker with a custom device
+#include "RMaker.h"
+#include "WiFi.h"
+#include "WiFiProv.h"
+
+#define DEFAULT_POWER_MODE   true
+#define DEFAULT_DIMMER_LEVEL 50
+const char *service_name = "PROV_1234";
+const char *pop = "abcd1234";
+
+//GPIO for push button
+#if CONFIG_IDF_TARGET_ESP32C3 || CONFIG_IDF_TARGET_ESP32C6
+static int gpio_0 = 9;
+static int gpio_dimmer = 7;
+#else
+//GPIO for virtual device
+static int gpio_0 = 0;
+static int gpio_dimmer = 16;
+#endif
+
+bool dimmer_state = true;
+
+// The framework provides some standard device types like switch, lightbulb, fan, temperature sensor.
+// But, you can also define custom devices using the 'Device' base class object, as shown here
+static Device *my_device = NULL;
+
+// WARNING: sysProvEvent is called from a separate FreeRTOS task (thread)!
+void sysProvEvent(arduino_event_t *sys_event) {
+  switch (sys_event->event_id) {
+    case ARDUINO_EVENT_PROV_START:
+#if CONFIG_IDF_TARGET_ESP32S2
+      Serial.printf("\nProvisioning Started with name \"%s\" and PoP \"%s\" on SoftAP\n", service_name, pop);
+      WiFiProv.printQR(service_name, pop, "softap");
+#else
+      Serial.printf("\nProvisioning Started with name \"%s\" and PoP \"%s\" on BLE\n", service_name, pop);
+      WiFiProv.printQR(service_name, pop, "ble");
+#endif
+      break;
+    case ARDUINO_EVENT_PROV_INIT:         WiFiProv.disableAutoStop(10000); break;
+    case ARDUINO_EVENT_PROV_CRED_SUCCESS: WiFiProv.endProvision(); break;
+    default:                              ;
+  }
+}
+
+void write_callback(Device *device, Param *param, const param_val_t val, void *priv_data, write_ctx_t *ctx) {
+  const char *device_name = device->getDeviceName();
+  const char *param_name = param->getParamName();
+
+  if (strcmp(param_name, "Power") == 0) {
+    Serial.printf("Received value = %s for %s - %s\n", val.val.b ? "true" : "false", device_name, param_name);
+    dimmer_state = val.val.b;
+    (dimmer_state == false) ? digitalWrite(gpio_dimmer, LOW) : digitalWrite(gpio_dimmer, HIGH);
+    param->updateAndReport(val);
+  } else if (strcmp(param_name, "Level") == 0) {
+    Serial.printf("\nReceived value = %d for %s - %s\n", val.val.i, device_name, param_name);
+    param->updateAndReport(val);
+  }
+}
+
+void setup() {
+  Serial.begin(115200);
+  pinMode(gpio_0, INPUT);
+  pinMode(gpio_dimmer, OUTPUT);
+  digitalWrite(gpio_dimmer, DEFAULT_POWER_MODE);
+
+  Node my_node;
+  my_node = RMaker.initNode("ESP RainMaker Node");
+  my_device = new Device("Dimmer", "custom.device.dimmer", &gpio_dimmer);
+  if (!my_device) {
+    return;
+  }
+  //Create custom dimmer device
+  my_device->addNameParam();
+  my_device->addPowerParam(DEFAULT_POWER_MODE);
+  my_device->assignPrimaryParam(my_device->getParamByName(ESP_RMAKER_DEF_POWER_NAME));
+
+  //Create and add a custom level parameter
+  Param level_param("Level", "custom.param.level", value(DEFAULT_DIMMER_LEVEL), PROP_FLAG_READ | PROP_FLAG_WRITE);
+  level_param.addBounds(value(0), value(100), value(1));
+  level_param.addUIType(ESP_RMAKER_UI_SLIDER);
+  my_device->addParam(level_param);
+
+  my_device->addCb(write_callback);
+
+  //Add custom dimmer device to the node
+  my_node.addDevice(*my_device);
+
+  //This is optional
+  RMaker.enableOTA(OTA_USING_TOPICS);
+  //If you want to enable scheduling, set time zone for your region using setTimeZone().
+  //The list of available values are provided here https://rainmaker.espressif.com/docs/time-service.html
+  // RMaker.setTimeZone("Asia/Shanghai");
+  // Alternatively, enable the Timezone service and let the phone apps set the appropriate timezone
+  RMaker.enableTZService();
+
+  RMaker.enableSchedule();
+
+  RMaker.enableScenes();
+
+  RMaker.start();
+
+  WiFi.onEvent(sysProvEvent);  // Will call sysProvEvent() from another thread.
+#if CONFIG_IDF_TARGET_ESP32S2
+  WiFiProv.beginProvision(NETWORK_PROV_SCHEME_SOFTAP, NETWORK_PROV_SCHEME_HANDLER_NONE, NETWORK_PROV_SECURITY_1, pop, service_name);
+#else
+  WiFiProv.beginProvision(NETWORK_PROV_SCHEME_BLE, NETWORK_PROV_SCHEME_HANDLER_FREE_BTDM, NETWORK_PROV_SECURITY_1, pop, service_name);
+#endif
+}
+
+void loop() {
+  if (digitalRead(gpio_0) == LOW) {  //Push button pressed
+
+    // Key debounce handling
+    delay(100);
+    int startTime = millis();
+    while (digitalRead(gpio_0) == LOW) {
+      delay(50);
+    }
+    int endTime = millis();
+
+    if ((endTime - startTime) > 10000) {
+      // If key pressed for more than 10secs, reset all
+      Serial.printf("Reset to factory.\n");
+      RMakerFactoryReset(2);
+    } else if ((endTime - startTime) > 3000) {
+      Serial.printf("Reset Wi-Fi.\n");
+      // If key pressed for more than 3secs, but less than 10, reset Wi-Fi
+      RMakerWiFiReset(2);
+    } else {
+      // Toggle device state
+      dimmer_state = !dimmer_state;
+      Serial.printf("Toggle State to %s.\n", dimmer_state ? "true" : "false");
+      if (my_device) {
+        my_device->updateAndReportParam(ESP_RMAKER_DEF_POWER_NAME, dimmer_state);
+      }
+      (dimmer_state == false) ? digitalWrite(gpio_dimmer, LOW) : digitalWrite(gpio_dimmer, HIGH);
+    }
+  }
+  delay(100);
+}

libraries/RainMaker/examples/RMakerCustom/ci.yml

@@ -0,0 +1,11 @@
+targets:
+  esp32: false
+
+fqbn_append: PartitionScheme=rainmaker_4MB
+
+requires:
+  - CONFIG_ESP_RMAKER_WORK_QUEUE_TASK_STACK=[1-9][0-9]*
+
+requires_any:
+  - CONFIG_SOC_WIFI_SUPPORTED=y
+  - CONFIG_ESP_WIFI_REMOTE_ENABLED=y

libraries/RainMaker/examples/RMakerCustomAirCooler/README.md

@@ -0,0 +1,34 @@
+# ESP RainMaker Custom Device
+
+This example demonstrates how to build a custom device to be used with ESP RainMaker using Mode, Range and Toggle Parameters.
+
+## What to expect in this example?
+
+- This example sketch uses the on board Boot button and GPIOs 16, 17, 18, 19, 21, 22 to demonstrate an ESP RainMaker AirCooler device.
+- After compiling and flashing the example, add your device using the [ESP RainMaker phone apps](https://rainmaker.espressif.com/docs/quick-links.html#phone-apps) by scanning the QR code.
+- Toggling the power state from the phone app will toggle GPIO 16.
+- Pressing the Boot button will toggle the power state (GPIO 16) and the same will reflect on the phone app.
+- Toggling the swing state from the phone app will toggle GPIO 17.
+- Changing the mode from the phone app will toggle the GPIOs 18 (auto), 19 (cool) and 21 (heat)
+- Changing the Speed slider from the phone app will dimming GPIO 22
+- You can also change the Level from the phone app and see it reflect on the device as a print message.
+
+### Output
+
+```
+Received value = true for Air Cooler - Power
+Received value = false for Air Cooler - Power
+Received value = true for Air Cooler - Swing
+Received value = false for Air Cooler - Swing
+Received value = 0 for Air Cooler - Speed
+Received value = 255 for Air Cooler - Speed
+Received value = Auto for Air Cooler - Mode
+Received value = Cool for Air Cooler - Mode
+Received value = Heat for Air Cooler - Mode
+Toggle power state to false.
+Toggle power state to false.
+```
+
+### Resetting the device
+- Press and Hold the Boot button for more than 3 seconds and then release to reset Wi-Fi configuration.
+- Press and Hold the Boot button for more than 10 seconds and then release to reset to factory defaults.

libraries/RainMaker/examples/RMakerCustomAirCooler/RMakerCustomAirCooler.ino

@@ -0,0 +1,205 @@
+//This example demonstrates the ESP RainMaker with a custom Air Cooler device
+#include "RMaker.h"
+#include "WiFi.h"
+#include "WiFiProv.h"
+
+#define DEFAULT_POWER_MODE true
+#define DEFAULT_SWING      false
+#define DEFAULT_SPEED      0
+#define DEFAULT_MODE       "Auto"
+
+const char *service_name = "PROV_1234";
+const char *pop = "abcd1234";
+
+#if CONFIG_IDF_TARGET_ESP32C3 || CONFIG_IDF_TARGET_ESP32C6
+//GPIO for push button
+static int gpio_reset = 9;
+//GPIO for virtual device
+static int gpio_power = 7;
+static int gpio_swing = 3;
+static int gpio_mode_auto = 4;
+static int gpio_mode_cool = 5;
+static int gpio_mode_heat = 6;
+static int gpio_speed = 10;
+
+#else
+//GPIO for push button
+static int gpio_reset = 0;
+//GPIO for virtual device
+static int gpio_power = 16;
+static int gpio_swing = 17;
+static int gpio_mode_auto = 18;
+static int gpio_mode_cool = 19;
+static int gpio_mode_heat = 21;
+static int gpio_speed = 22;
+#endif
+
+bool power_state = true;
+
+// The framework provides some standard device types like switch, lightbulb, fan, temperature sensor.
+// But, you can also define custom devices using the 'Device' base class object, as shown here
+static Device *my_device = NULL;
+
+// WARNING: sysProvEvent is called from a separate FreeRTOS task (thread)!
+void sysProvEvent(arduino_event_t *sys_event) {
+  switch (sys_event->event_id) {
+    case ARDUINO_EVENT_PROV_START:
+#if CONFIG_IDF_TARGET_ESP32S2
+      Serial.printf("\nProvisioning Started with name \"%s\" and PoP \"%s\" on SoftAP\n", service_name, pop);
+      WiFiProv.printQR(service_name, pop, "softap");
+#else
+      Serial.printf("\nProvisioning Started with name \"%s\" and PoP \"%s\" on BLE\n", service_name, pop);
+      WiFiProv.printQR(service_name, pop, "ble");
+#endif
+      break;
+    case ARDUINO_EVENT_PROV_INIT:         WiFiProv.disableAutoStop(10000); break;
+    case ARDUINO_EVENT_PROV_CRED_SUCCESS: WiFiProv.endProvision(); break;
+    default:                              ;
+  }
+}
+
+void write_callback(Device *device, Param *param, const param_val_t val, void *priv_data, write_ctx_t *ctx) {
+  const char *device_name = device->getDeviceName();
+  const char *param_name = param->getParamName();
+
+  if (strcmp(param_name, "Power") == 0) {
+    Serial.printf("Received value = %s for %s - %s\n", val.val.b ? "true" : "false", device_name, param_name);
+    power_state = val.val.b;
+    (power_state == false) ? digitalWrite(gpio_power, LOW) : digitalWrite(gpio_power, HIGH);
+    param->updateAndReport(val);
+  } else if (strcmp(param_name, "Swing") == 0) {
+    Serial.printf("\nReceived value = %s for %s - %s\n", val.val.b ? "true" : "false", device_name, param_name);
+    bool swing = val.val.b;
+    (swing == false) ? digitalWrite(gpio_swing, LOW) : digitalWrite(gpio_swing, HIGH);
+    param->updateAndReport(val);
+  } else if (strcmp(param_name, "Speed") == 0) {
+    Serial.printf("\nReceived value = %d for %s - %s\n", val.val.i, device_name, param_name);
+    int speed = val.val.i;
+    analogWrite(gpio_speed, speed);
+    param->updateAndReport(val);
+  } else if (strcmp(param_name, "Mode") == 0) {
+    const char *mode = val.val.s;
+    if (strcmp(mode, "Auto") == 0) {
+      digitalWrite(gpio_mode_auto, HIGH);
+      digitalWrite(gpio_mode_heat, LOW);
+      digitalWrite(gpio_mode_cool, LOW);
+    } else if (strcmp(mode, "Heat") == 0) {
+      digitalWrite(gpio_mode_auto, LOW);
+      digitalWrite(gpio_mode_heat, HIGH);
+      digitalWrite(gpio_mode_cool, LOW);
+    } else if (strcmp(mode, "Cool") == 0) {
+      digitalWrite(gpio_mode_auto, LOW);
+      digitalWrite(gpio_mode_heat, LOW);
+      digitalWrite(gpio_mode_cool, HIGH);
+    }
+    Serial.printf("\nReceived value = %s for %s - %s\n", val.val.s, device_name, param_name);
+    param->updateAndReport(val);
+  }
+}
+
+void setup() {
+  Serial.begin(115200);
+  pinMode(gpio_reset, INPUT_PULLUP);
+  pinMode(gpio_power, OUTPUT);
+  digitalWrite(gpio_power, DEFAULT_POWER_MODE);
+  pinMode(gpio_swing, OUTPUT);
+  digitalWrite(gpio_swing, DEFAULT_SWING);
+  pinMode(gpio_mode_auto, OUTPUT);
+  if (strcmp(DEFAULT_MODE, "Auto") == 0) {
+    digitalWrite(gpio_mode_auto, HIGH);
+  }
+  pinMode(gpio_mode_cool, OUTPUT);
+  if (strcmp(DEFAULT_MODE, "Cool") == 0) {
+    digitalWrite(gpio_mode_auto, HIGH);
+  }
+  pinMode(gpio_mode_heat, OUTPUT);
+  if (strcmp(DEFAULT_MODE, "Heat") == 0) {
+    digitalWrite(gpio_mode_auto, HIGH);
+  }
+  pinMode(gpio_speed, OUTPUT);
+  analogWrite(gpio_speed, DEFAULT_SPEED);
+
+  Node my_node;
+  my_node = RMaker.initNode("ESP RainMaker Node");
+  my_device = new Device("Air Cooler", "my.device.air-cooler", NULL);
+  if (!my_device) {
+    return;
+  }
+  //Create custom air cooler device
+  my_device->addNameParam();
+  my_device->addPowerParam(DEFAULT_POWER_MODE);
+  my_device->assignPrimaryParam(my_device->getParamByName(ESP_RMAKER_DEF_POWER_NAME));
+
+  Param swing("Swing", ESP_RMAKER_PARAM_TOGGLE, value(DEFAULT_SWING), PROP_FLAG_READ | PROP_FLAG_WRITE);
+  swing.addUIType(ESP_RMAKER_UI_TOGGLE);
+  my_device->addParam(swing);
+
+  Param speed("Speed", ESP_RMAKER_PARAM_RANGE, value(DEFAULT_SPEED), PROP_FLAG_READ | PROP_FLAG_WRITE);
+  speed.addUIType(ESP_RMAKER_UI_SLIDER);
+  speed.addBounds(value(0), value(255), value(1));
+  my_device->addParam(speed);
+
+  static const char *modes[] = {"Auto", "Cool", "Heat"};
+  Param mode_param("Mode", ESP_RMAKER_PARAM_MODE, value("Auto"), PROP_FLAG_READ | PROP_FLAG_WRITE);
+  mode_param.addValidStrList(modes, 3);
+  mode_param.addUIType(ESP_RMAKER_UI_DROPDOWN);
+  my_device->addParam(mode_param);
+
+  my_device->addCb(write_callback);
+
+  //Add custom Air Cooler device to the node
+  my_node.addDevice(*my_device);
+
+  //This is optional
+  // RMaker.enableOTA(OTA_USING_TOPICS);
+  //If you want to enable scheduling, set time zone for your region using setTimeZone().
+  //The list of available values are provided here https://rainmaker.espressif.com/docs/time-service.html
+  // RMaker.setTimeZone("Asia/Shanghai");
+  //Alternatively, enable the Timezone service and let the phone apps set the appropriate timezone
+  // RMaker.enableTZService();
+
+  RMaker.enableSchedule();
+
+  RMaker.enableScenes();
+
+  RMaker.start();
+
+  WiFi.onEvent(sysProvEvent);  // Will call sysProvEvent() from another thread.
+#if CONFIG_IDF_TARGET_ESP32S2
+  WiFiProv.beginProvision(NETWORK_PROV_SCHEME_SOFTAP, NETWORK_PROV_SCHEME_HANDLER_NONE, NETWORK_PROV_SECURITY_1, pop, service_name);
+#else
+  WiFiProv.beginProvision(NETWORK_PROV_SCHEME_BLE, NETWORK_PROV_SCHEME_HANDLER_FREE_BTDM, NETWORK_PROV_SECURITY_1, pop, service_name);
+#endif
+}
+
+void loop() {
+  if (digitalRead(gpio_reset) == LOW) {  //Push button pressed
+
+    // Key debounce handling
+    delay(100);
+    int startTime = millis();
+    while (digitalRead(gpio_reset) == LOW) {
+      delay(50);
+    }
+    int press_duration = millis() - startTime;
+
+    if (press_duration > 10000) {
+      // If key pressed for more than 10secs, reset all
+      Serial.printf("Reset to factory.\n");
+      RMakerFactoryReset(2);
+    } else if (press_duration > 3000) {
+      Serial.printf("Reset Wi-Fi.\n");
+      // If key pressed for more than 3secs, but less than 10, reset Wi-Fi
+      RMakerWiFiReset(2);
+    } else {
+      // Toggle device state
+      power_state = !power_state;
+      Serial.printf("Toggle power state to %s.\n", power_state ? "true" : "false");
+      if (my_device) {
+        my_device->updateAndReportParam(ESP_RMAKER_DEF_POWER_NAME, power_state);
+      }
+      (power_state == false) ? digitalWrite(gpio_power, LOW) : digitalWrite(gpio_power, HIGH);
+    }
+  }
+  delay(100);
+}

libraries/RainMaker/examples/RMakerCustomAirCooler/ci.yml

@@ -0,0 +1,11 @@
+targets:
+  esp32: false
+
+fqbn_append: PartitionScheme=rainmaker_4MB
+
+requires:
+  - CONFIG_ESP_RMAKER_WORK_QUEUE_TASK_STACK=[1-9][0-9]*
+
+requires_any:
+  - CONFIG_SOC_WIFI_SUPPORTED=y
+  - CONFIG_ESP_WIFI_REMOTE_ENABLED=y

libraries/RainMaker/examples/RMakerSonoffDualR3/RMakerSonoffDualR3.ino

@@ -0,0 +1,206 @@
+//This example demonstrates the ESP RainMaker with a standard Switch device.
+#include "RMaker.h"
+#include "WiFi.h"
+#include "WiFiProv.h"
+
+#define DEFAULT_POWER_MODE false
+const char *service_name = "PROV_SONOFF_DUALR3";
+const char *pop = "123456";
+
+// GPIO for push button
+static uint8_t gpio_reset = 0;
+// GPIO for switch
+static uint8_t gpio_switch1 = 32;
+static uint8_t gpio_switch2 = 33;
+// GPIO for virtual device
+static uint8_t gpio_relay1 = 27;
+static uint8_t gpio_relay2 = 14;
+/* Variable for reading pin status*/
+bool switch_state_ch1 = true;
+bool switch_state_ch2 = true;
+// GPIO for link status LED
+static uint8_t gpio_led = 13;
+
+struct LightSwitch {
+  const uint8_t pin;
+  bool pressed;
+};
+
+// Define the light switches for channel 1 and 2
+LightSwitch switch_ch1 = {gpio_switch1, false};
+LightSwitch switch_ch2 = {gpio_switch2, false};
+
+//The framework provides some standard device types like switch, lightbulb, fan, temperature sensor.
+static Switch *my_switch1 = NULL;
+static Switch *my_switch2 = NULL;
+
+// WARNING: sysProvEvent is called from a separate FreeRTOS task (thread)!
+void sysProvEvent(arduino_event_t *sys_event) {
+  switch (sys_event->event_id) {
+    case ARDUINO_EVENT_PROV_START:
+#if CONFIG_IDF_TARGET_ESP32
+      Serial.printf("\nProvisioning Started with name \"%s\" and PoP \"%s\" on BLE\n", service_name, pop);
+      WiFiProv.printQR(service_name, pop, "ble");
+#else
+      Serial.printf("\nProvisioning Started with name \"%s\" and PoP \"%s\" on SoftAP\n", service_name, pop);
+      WiFiProv.printQR(service_name, pop, "softap");
+#endif
+      break;
+    case ARDUINO_EVENT_WIFI_STA_CONNECTED:
+      Serial.printf("\nConnected to Wi-Fi!\n");
+      digitalWrite(gpio_led, true);
+      break;
+    case ARDUINO_EVENT_PROV_INIT:         WiFiProv.disableAutoStop(10000); break;
+    case ARDUINO_EVENT_PROV_CRED_SUCCESS: WiFiProv.endProvision(); break;
+    default:                              ;
+  }
+}
+
+void write_callback(Device *device, Param *param, const param_val_t val, void *priv_data, write_ctx_t *ctx) {
+  const char *device_name = device->getDeviceName();
+  const char *param_name = param->getParamName();
+
+  if (strcmp(device_name, "Switch_ch1") == 0) {
+
+    Serial.printf("Lightbulb = %s\n", val.val.b ? "true" : "false");
+
+    if (strcmp(param_name, "Power") == 0) {
+      Serial.printf("Received value = %s for %s - %s\n", val.val.b ? "true" : "false", device_name, param_name);
+      switch_state_ch1 = val.val.b;
+      (switch_state_ch1 == false) ? digitalWrite(gpio_relay1, LOW) : digitalWrite(gpio_relay1, HIGH);
+      param->updateAndReport(val);
+    }
+
+  } else if (strcmp(device_name, "Switch_ch2") == 0) {
+
+    Serial.printf("Switch value = %s\n", val.val.b ? "true" : "false");
+
+    if (strcmp(param_name, "Power") == 0) {
+      Serial.printf("Received value = %s for %s - %s\n", val.val.b ? "true" : "false", device_name, param_name);
+      switch_state_ch2 = val.val.b;
+      (switch_state_ch2 == false) ? digitalWrite(gpio_relay2, LOW) : digitalWrite(gpio_relay2, HIGH);
+      param->updateAndReport(val);
+    }
+  }
+}
+
+void ARDUINO_ISR_ATTR isr(void *arg) {
+  LightSwitch *s = static_cast<LightSwitch *>(arg);
+  s->pressed = true;
+}
+
+void setup() {
+
+  uint32_t chipId = 0;
+
+  Serial.begin(115200);
+
+  // Configure the input GPIOs
+  pinMode(gpio_reset, INPUT);
+  pinMode(switch_ch1.pin, INPUT_PULLUP);
+  attachInterruptArg(switch_ch1.pin, isr, &switch_ch1, CHANGE);
+  pinMode(switch_ch2.pin, INPUT_PULLUP);
+  attachInterruptArg(switch_ch2.pin, isr, &switch_ch2, CHANGE);
+
+  // Set the Relays GPIOs as output mode
+  pinMode(gpio_relay1, OUTPUT);
+  pinMode(gpio_relay2, OUTPUT);
+  pinMode(gpio_led, OUTPUT);
+  // Write to the GPIOs the default state on booting
+  digitalWrite(gpio_relay1, DEFAULT_POWER_MODE);
+  digitalWrite(gpio_relay2, DEFAULT_POWER_MODE);
+  digitalWrite(gpio_led, false);
+
+  Node my_node;
+  my_node = RMaker.initNode("Sonoff Dual R3");
+
+  //Initialize switch device
+  my_switch1 = new Switch("Switch_ch1", &gpio_relay1);
+  my_switch2 = new Switch("Switch_ch2", &gpio_relay2);
+
+  if (!my_switch1 || !my_switch2) {
+    return;
+  }
+  //Standard switch device
+  my_switch1->addCb(write_callback);
+  my_switch2->addCb(write_callback);
+
+  //Add switch device to the node
+  my_node.addDevice(*my_switch1);
+  my_node.addDevice(*my_switch2);
+
+  //This is optional
+  RMaker.enableOTA(OTA_USING_TOPICS);
+  //If you want to enable scheduling, set time zone for your region using setTimeZone().
+  //The list of available values are provided here https://rainmaker.espressif.com/docs/time-service.html
+  // RMaker.setTimeZone("Asia/Shanghai");
+  // Alternatively, enable the Timezone service and let the phone apps set the appropriate timezone
+  RMaker.enableTZService();
+  RMaker.enableSchedule();
+  RMaker.enableScenes();
+
+  //Service Name
+  for (int i = 0; i < 17; i = i + 8) {
+    chipId |= ((ESP.getEfuseMac() >> (40 - i)) & 0xff) << i;
+  }
+
+  Serial.printf("\nChip ID:  %lu Service Name: %s\n", chipId, service_name);
+
+  Serial.printf("\nStarting ESP-RainMaker\n");
+  RMaker.start();
+
+  WiFi.onEvent(sysProvEvent);  // Will call sysProvEvent() from another thread.
+#if CONFIG_IDF_TARGET_ESP32
+  WiFiProv.beginProvision(NETWORK_PROV_SCHEME_BLE, NETWORK_PROV_SCHEME_HANDLER_FREE_BTDM, NETWORK_PROV_SECURITY_1, pop, service_name);
+#else
+  WiFiProv.beginProvision(NETWORK_PROV_SCHEME_SOFTAP, NETWORK_PROV_SCHEME_HANDLER_NONE, NETWORK_PROV_SECURITY_1, pop, service_name);
+#endif
+}
+
+void loop() {
+
+  if (switch_ch1.pressed) {
+    Serial.printf("Switch 1 has been changed\n");
+    switch_ch1.pressed = false;
+    // Toggle switch 1 device state
+    switch_state_ch1 = !switch_state_ch1;
+    Serial.printf("Toggle State to %s.\n", switch_state_ch1 ? "true" : "false");
+    if (my_switch1) {
+      my_switch1->updateAndReportParam(ESP_RMAKER_DEF_POWER_NAME, switch_state_ch1);
+    }
+    (switch_state_ch1 == false) ? digitalWrite(gpio_relay1, LOW) : digitalWrite(gpio_relay1, HIGH);
+  } else if (switch_ch2.pressed) {
+    Serial.printf("Switch 2 has been changed\n");
+    switch_ch2.pressed = false;
+    // Toggle switch 2 device state
+    switch_state_ch2 = !switch_state_ch2;
+    Serial.printf("Toggle State to %s.\n", switch_state_ch2 ? "true" : "false");
+    if (my_switch2) {
+      my_switch2->updateAndReportParam(ESP_RMAKER_DEF_POWER_NAME, switch_state_ch2);
+    }
+    (switch_state_ch2 == false) ? digitalWrite(gpio_relay2, LOW) : digitalWrite(gpio_relay2, HIGH);
+  }
+
+  // Read GPIO0 (external button to reset device
+  if (digitalRead(gpio_reset) == LOW) {  //Push button pressed
+    Serial.printf("Reset Button Pressed!\n");
+    // Key debounce handling
+    delay(100);
+    int startTime = millis();
+    while (digitalRead(gpio_reset) == LOW) {
+      delay(50);
+    }
+    int endTime = millis();
+
+    if ((endTime - startTime) > 10000) {
+      // If key pressed for more than 10secs, reset all
+      Serial.printf("Reset to factory.\n");
+      RMakerFactoryReset(2);
+    } else if ((endTime - startTime) > 3000) {
+      Serial.printf("Reset Wi-Fi.\n");
+      // If key pressed for more than 3secs, but less than 10, reset Wi-Fi
+      RMakerWiFiReset(2);
+    }
+  }
+  delay(100);
+}

libraries/RainMaker/examples/RMakerSonoffDualR3/ci.yml

@@ -0,0 +1,11 @@
+targets:
+  esp32: false
+
+fqbn_append: PartitionScheme=rainmaker_4MB
+
+requires:
+  - CONFIG_ESP_RMAKER_WORK_QUEUE_TASK_STACK=[1-9][0-9]*
+
+requires_any:
+  - CONFIG_SOC_WIFI_SUPPORTED=y
+  - CONFIG_ESP_WIFI_REMOTE_ENABLED=y

libraries/RainMaker/examples/RMakerSwitch/README.md

@@ -0,0 +1,31 @@
+# ESP RainMaker Switch
+
+This example demonstrates how to build a switch device to be used with ESP RainMaker.
+
+## What to expect in this example?
+
+- This example sketch uses the on board Boot button and GPIO16 to demonstrate an ESP RainMaker switch device.
+- After compiling and flashing the example, add your device using the [ESP RainMaker phone apps](https://rainmaker.espressif.com/docs/quick-links.html#phone-apps) by scanning the QR code.
+- Toggling the state from the phone app will toggle the switch state (GPIO16).
+- Pressing the Boot button will toggle the switch state (GPIO16) and the same will reflect on the phone app.
+
+### Output
+
+```
+[    63][I][RMaker.cpp:13] event_handler(): RainMaker Initialized.
+[    69][I][WiFiProv.cpp:158] beginProvision(): Already Provisioned
+[    69][I][WiFiProv.cpp:162] beginProvision(): Attempting connect to AP: Viking007_2GEXT
+
+Toggle State to false.
+[  8182][I][RMakerDevice.cpp:162] updateAndReportParam(): Device : Switch, Param Name : Power, Val : false
+Toggle State to true.
+[  9835][I][RMakerDevice.cpp:162] updateAndReportParam(): Device : Switch, Param Name : Power, Val : true
+Received value = false for Switch - Power
+Received value = true for Switch - Power
+Toggle State to false.
+[ 29937][I][RMakerDevice.cpp:162] updateAndReportParam(): Device : Switch, Param Name : Power, Val : false
+```
+
+### Resetting the device
+- Press and Hold the Boot button for more than 3 seconds and then release to reset Wi-Fi configuration.
+- Press and Hold the Boot button for more than 10 seconds and then release to reset to factory defaults.

libraries/RainMaker/examples/RMakerSwitch/RMakerSwitch.ino

@@ -0,0 +1,143 @@
+// This example demonstrates the ESP RainMaker with a standard Switch device.
+#include "RMaker.h"
+#include "WiFi.h"
+#include "WiFiProv.h"
+#include "AppInsights.h"
+
+#define DEFAULT_POWER_MODE true
+const char *service_name = "PROV_1234";
+const char *pop = "abcd1234";
+
+// GPIO for push button
+#if CONFIG_IDF_TARGET_ESP32C3 || CONFIG_IDF_TARGET_ESP32C6
+static int gpio_0 = 9;
+static int gpio_switch = 7;
+#else
+// GPIO for virtual device
+static int gpio_0 = 0;
+static int gpio_switch = 16;
+#endif
+
+/* Variable for reading pin status*/
+bool switch_state = true;
+
+// The framework provides some standard device types like switch, lightbulb,
+// fan, temperaturesensor.
+static Switch *my_switch = NULL;
+
+// WARNING: sysProvEvent is called from a separate FreeRTOS task (thread)!
+void sysProvEvent(arduino_event_t *sys_event) {
+  switch (sys_event->event_id) {
+    case ARDUINO_EVENT_PROV_START:
+#if CONFIG_IDF_TARGET_ESP32S2
+      Serial.printf("\nProvisioning Started with name \"%s\" and PoP \"%s\" on SoftAP\n", service_name, pop);
+      WiFiProv.printQR(service_name, pop, "softap");
+#else
+      Serial.printf("\nProvisioning Started with name \"%s\" and PoP \"%s\" on BLE\n", service_name, pop);
+      WiFiProv.printQR(service_name, pop, "ble");
+#endif
+      break;
+    case ARDUINO_EVENT_PROV_INIT:         WiFiProv.disableAutoStop(10000); break;
+    case ARDUINO_EVENT_PROV_CRED_SUCCESS: WiFiProv.endProvision(); break;
+    default:                              ;
+  }
+}
+
+void write_callback(Device *device, Param *param, const param_val_t val, void *priv_data, write_ctx_t *ctx) {
+  const char *device_name = device->getDeviceName();
+  const char *param_name = param->getParamName();
+
+  if (strcmp(param_name, "Power") == 0) {
+    Serial.printf("Received value = %s for %s - %s\n", val.val.b ? "true" : "false", device_name, param_name);
+    switch_state = val.val.b;
+    (switch_state == false) ? digitalWrite(gpio_switch, LOW) : digitalWrite(gpio_switch, HIGH);
+    param->updateAndReport(val);
+  }
+}
+
+void setup() {
+  Serial.begin(115200);
+  pinMode(gpio_0, INPUT);
+  pinMode(gpio_switch, OUTPUT);
+  digitalWrite(gpio_switch, DEFAULT_POWER_MODE);
+
+  Node my_node;
+  my_node = RMaker.initNode("ESP RainMaker Node");
+
+  // Initialize switch device
+  my_switch = new Switch("Switch", &gpio_switch);
+  if (!my_switch) {
+    return;
+  }
+  // Standard switch device
+  my_switch->addCb(write_callback);
+
+  // Add switch device to the node
+  my_node.addDevice(*my_switch);
+
+  // This is optional
+  RMaker.enableOTA(OTA_USING_TOPICS);
+  // If you want to enable scheduling, set time zone for your region using
+  // setTimeZone(). The list of available values are provided here
+  // https://rainmaker.espressif.com/docs/time-service.html
+  //  RMaker.setTimeZone("Asia/Shanghai");
+  //  Alternatively, enable the Timezone service and let the phone apps set the
+  //  appropriate timezone
+  RMaker.enableTZService();
+
+  RMaker.enableSchedule();
+
+  RMaker.enableScenes();
+  // Enable ESP Insights. Insteads of using the default http transport, this function will
+  // reuse the existing MQTT connection of Rainmaker, thereby saving memory space.
+  initAppInsights();
+
+  RMaker.enableSystemService(SYSTEM_SERV_FLAGS_ALL, 2, 2, 2);
+
+#if CONFIG_IDF_TARGET_ESP32S2
+  WiFiProv.initProvision(NETWORK_PROV_SCHEME_SOFTAP, NETWORK_PROV_SCHEME_HANDLER_NONE);
+#else
+  WiFiProv.initProvision(NETWORK_PROV_SCHEME_BLE, NETWORK_PROV_SCHEME_HANDLER_FREE_BTDM);
+#endif
+
+  RMaker.start();
+
+  WiFi.onEvent(sysProvEvent);  // Will call sysProvEvent() from another thread.
+#if CONFIG_IDF_TARGET_ESP32S2
+  WiFiProv.beginProvision(NETWORK_PROV_SCHEME_SOFTAP, NETWORK_PROV_SCHEME_HANDLER_NONE, NETWORK_PROV_SECURITY_1, pop, service_name);
+#else
+  WiFiProv.beginProvision(NETWORK_PROV_SCHEME_BLE, NETWORK_PROV_SCHEME_HANDLER_FREE_BTDM, NETWORK_PROV_SECURITY_1, pop, service_name);
+#endif
+}
+
+void loop() {
+  if (digitalRead(gpio_0) == LOW) {  // Push button pressed
+
+    // Key debounce handling
+    delay(100);
+    int startTime = millis();
+    while (digitalRead(gpio_0) == LOW) {
+      delay(50);
+    }
+    int endTime = millis();
+
+    if ((endTime - startTime) > 10000) {
+      // If key pressed for more than 10secs, reset all
+      Serial.printf("Reset to factory.\n");
+      RMakerFactoryReset(2);
+    } else if ((endTime - startTime) > 3000) {
+      Serial.printf("Reset Wi-Fi.\n");
+      // If key pressed for more than 3secs, but less than 10, reset Wi-Fi
+      RMakerWiFiReset(2);
+    } else {
+      // Toggle device state
+      switch_state = !switch_state;
+      Serial.printf("Toggle State to %s.\n", switch_state ? "true" : "false");
+      if (my_switch) {
+        my_switch->updateAndReportParam(ESP_RMAKER_DEF_POWER_NAME, switch_state);
+      }
+      (switch_state == false) ? digitalWrite(gpio_switch, LOW) : digitalWrite(gpio_switch, HIGH);
+    }
+  }
+  delay(100);
+}

libraries/RainMaker/examples/RMakerSwitch/ci.yml

@@ -0,0 +1,11 @@
+targets:
+  esp32: false
+
+fqbn_append: PartitionScheme=rainmaker_4MB
+
+requires:
+  - CONFIG_ESP_RMAKER_WORK_QUEUE_TASK_STACK=[1-9][0-9]*
+
+requires_any:
+  - CONFIG_SOC_WIFI_SUPPORTED=y
+  - CONFIG_ESP_WIFI_REMOTE_ENABLED=y