3.3.7

libraries/Wire/examples/WireMaster/WireMaster.ino

@@ -0,0 +1,30 @@
+#include "Wire.h"
+
+#define I2C_DEV_ADDR 0x55
+
+uint32_t i = 0;
+
+void setup() {
+  Serial.begin(115200);
+  Serial.setDebugOutput(true);
+  Wire.begin();
+}
+
+void loop() {
+  delay(5000);
+
+  //Write message to the slave
+  Wire.beginTransmission(I2C_DEV_ADDR);
+  Wire.printf("Hello World! %lu", i++);
+  uint8_t error = Wire.endTransmission(true);
+  Serial.printf("endTransmission: %u\n", error);
+
+  //Read 16 bytes from the slave
+  uint8_t bytesReceived = Wire.requestFrom(I2C_DEV_ADDR, 16);
+  Serial.printf("requestFrom: %u\n", bytesReceived);
+  if ((bool)bytesReceived) {  //If received more than zero bytes
+    uint8_t temp[bytesReceived];
+    Wire.readBytes(temp, bytesReceived);
+    log_print_buf(temp, bytesReceived);
+  }
+}

libraries/Wire/examples/WireMaster/ci.yml

@@ -0,0 +1,2 @@
+requires:
+  - CONFIG_SOC_I2C_SUPPORTED=y

libraries/Wire/examples/WireScan/WireScan.ino

@@ -0,0 +1,28 @@
+#include "Wire.h"
+
+void setup() {
+  Serial.begin(115200);
+  Wire.begin();
+}
+
+void loop() {
+  byte error, address;
+  int nDevices = 0;
+
+  delay(5000);
+
+  Serial.println("Scanning for I2C devices ...");
+  for (address = 0x01; address < 0x7f; address++) {
+    Wire.beginTransmission(address);
+    error = Wire.endTransmission();
+    if (error == 0) {
+      Serial.printf("I2C device found at address 0x%02X\n", address);
+      nDevices++;
+    } else if (error != 2) {
+      Serial.printf("Error %d at address 0x%02X\n", error, address);
+    }
+  }
+  if (nDevices == 0) {
+    Serial.println("No I2C devices found");
+  }
+}

libraries/Wire/examples/WireScan/ci.yml

@@ -0,0 +1,2 @@
+requires:
+  - CONFIG_SOC_I2C_SUPPORTED=y

libraries/Wire/examples/WireSlave/WireSlave.ino

@@ -0,0 +1,35 @@
+#include "Wire.h"
+
+#define I2C_DEV_ADDR 0x55
+
+uint32_t i = 0;
+
+void onRequest() {
+  Wire.print(i++);
+  Wire.print(" Packets.");
+  Serial.println("onRequest");
+}
+
+void onReceive(int len) {
+  Serial.printf("onReceive[%d]: ", len);
+  while (Wire.available()) {
+    Serial.write(Wire.read());
+  }
+  Serial.println();
+}
+
+void setup() {
+  Serial.begin(115200);
+  Serial.setDebugOutput(true);
+  Wire.onReceive(onReceive);
+  Wire.onRequest(onRequest);
+  Wire.begin((uint8_t)I2C_DEV_ADDR);
+
+#if CONFIG_IDF_TARGET_ESP32
+  char message[64];
+  snprintf(message, 64, "%lu Packets.", i++);
+  Wire.slaveWrite((uint8_t *)message, strlen(message));
+#endif
+}
+
+void loop() {}

libraries/Wire/examples/WireSlave/ci.yml

@@ -0,0 +1,2 @@
+requires:
+  - CONFIG_SOC_I2C_SUPPORT_SLAVE=y

libraries/Wire/examples/WireSlaveFunctionalCallback/WireSlaveFunctionalCallback.ino

@@ -0,0 +1,37 @@
+// This example demonstrates the use of functional callbacks with the Wire library
+// for I2C slave communication. It shows how to handle requests and data reception
+
+#include "Wire.h"
+
+#define I2C_DEV_ADDR 0x55
+
+uint32_t i = 0;
+
+void setup() {
+  Serial.begin(115200);
+  Serial.setDebugOutput(true);
+
+  Wire.onRequest([]() {
+    Wire.print(i++);
+    Wire.print(" Packets.");
+    Serial.println("onRequest");
+  });
+
+  Wire.onReceive([](int len) {
+    Serial.printf("onReceive[%d]: ", len);
+    while (Wire.available()) {
+      Serial.write(Wire.read());
+    }
+    Serial.println();
+  });
+
+  Wire.begin((uint8_t)I2C_DEV_ADDR);
+
+#if CONFIG_IDF_TARGET_ESP32
+  char message[64];
+  snprintf(message, 64, "%lu Packets.", i++);
+  Wire.slaveWrite((uint8_t *)message, strlen(message));
+#endif
+}
+
+void loop() {}

libraries/Wire/examples/WireSlaveFunctionalCallback/ci.yml

@@ -0,0 +1,2 @@
+requires:
+  - CONFIG_SOC_I2C_SUPPORT_SLAVE=y